Power BI,Power Pivot, DAX dynamischen Kalender erstellen

in Power BI Desktop in die Modellansicht wechseln,

neue Tabelle -> DAX einfügen: 

(hier auf Basis Abfrage (Power Query) Name financials, Feldname [Date],
entsprechend anpassen bei Übernahme in eigenes Datenmodell)

--- SCHNIPP mit ADDCOLUMNS()  --- 

Kalender_DAX = 

 //VAR StartDatum = EDATE(TODAY(),-48)

 //VAR EndDatum = EDATE(TODAY(),48)

 //VAR StartDatum =DATE(2013,1,1)

 //VAR EndDatum = DATE(2014,12,31)

 //oder mit DAX Funktionen FIRSTDATE,LASTDATE 


 VAR StartDatum = FIRSTDATE(financials[Date])

 VAR EndDatum = LASTDATE(financials[Date])

 

 RETURN

    ADDCOLUMNS(

        CALENDAR(StartDatum,EndDatum),

        "Jahr", YEAR([Date]),

        "GJ" , YEAR(EDATE([Date],9))-1 & "/" & YEAR(EDATE([Date],9)),

        "Jahr Monat", YEAR([Date])  &"."& MONTH([Date]),

        "Quartal", QUARTER([Date]),

        "Monat", MONTH([Date]),

        "Monatsname", FORMAT(MONTH([Date]),"mmmm"),

        "Tag", DAY([Date]),

        "KW", WEEKNUM([Date],1),

        "Jahr Monat Sortierung", YEAR([Date]) & UNICHAR(MONTH([Date]) + 64),

       "Datenschnitt Letzten 12 Monate", IF(DATEDIFF([Date],EndDatum,MONTH) <=6,"JA","NEIN"),

        "Datenschnitt Heute Gestern", IF([Date]=TODAY(), "HEUTE",

                            IF([Date] = TODAY()-1, "Gestern",

                            FORMAT([Date],"dd.mm.yyyy")

                            )

    )

)

--- SCHNAPP ---


DAX Kalender mit Geschäftsjahr

(hier auf Basis Abfrage (Power Query) Name financials, Feldname [Date],
entsprechend anpassen bei Übernahme in eigenes Datenmodell)


--- SCHNIPP mit CALENDERAUTO() und ROW() ---

Kalender_GJ_DAX =
VAR FirstFiscalMonth = 4 -- Erster Monat des Geschäftsjahres GJ
VAR FirstDayOfWeek = 1   -- 0 = Sonntag, 1 = Montag, ...
VAR FirstYear =          -- setzt das erste Jahr
    YEAR ( MIN ( financials[Date]  ))
RETURN
GENERATE (
    FILTER (
        CALENDARAUTO (),
        YEAR ( [Date] ) >= FirstYear
    ),
    VAR Yr = YEAR ( [Date] )            -- Jahr Nummer
    VAR Mn = MONTH ( [Date] )           -- Monat Nummer (1-12)
    VAR Qr = QUARTER ( [Date] )         -- Quartal Nummer (1-4)
    VAR MnQ = Mn - 3 * (Qr - 1)         -- Monat im Quartal (1-3)
    VAR Fyr =                           -- Geschäftsjahr Nummer
        Yr + 1 * ( FirstFiscalMonth > 1 && Mn >= FirstFiscalMonth )
    VAR Fqr =                           -- Geschäftsjahres Quartal (Zeichen)
        FORMAT ( EOMONTH ( [Date], 1 - FirstFiscalMonth ), "\QQ" )
    RETURN ROW (
        "KJ Enddatum", DATE ( Yr, 12, 31 ),
        "Quartal KJ", FORMAT ( [Date], "\QQ-YYYY" ),
        "KJ Quartal kurz", FORMAT ( [Date], "\QQ" ),
        "KJ Quartal Enddatum", EOMONTH ( [Date], 3 - MnQ ),
        "KJ Monatsende", EOMONTH ( [Date], 0 ), -- Monat Enddatum
        "KJ Monatsanfang", EOMONTH ( [Date], -1 ) + 1, -- Monat Startdatum
        "GJ Enddatum", DATE ( Fyr + (FirstFiscalMonth = 1), FirstFiscalMonth, 1 ) - 1,
        "GJ Quartal kurz", Fqr,
        "GJ Quartal Enddatum", EOMONTH ( [Date], 3 - MnQ ),
        "GJ", (Fyr - 1) & "/"& Fyr
    )
)


--- SCHNAPP ---

Kalender (Name Kalender_Filter) für relative Zeiträume (letzten 12 Monate usw.)
verknüpft über Spalte Kalender[Date] mit anderem Kalender (Name des Kalenders = Kalender),
Kreuzfilterrichtung BEIDE


siehe https://www.youtube.com/watch?v=fKygF7VEJnQ&t=525s



--- SCHNIPP mit UNION() und ADDCOLUMNS() ---

Kalender_Filter =

UNION(
ADDCOLUMNS(
DATESMTD(Kalender[Date]),
"Filter","MTD (Month-to-date)","Sortierung",1
),
ADDCOLUMNS(
DATESQTD(Kalender[Date]),
"Filter","QTD (Quarter-to-date)","Sortierung",2
),
ADDCOLUMNS(
DATESYTD(Kalender[Date]),
"Filter","YTD (Year-to-date)","Sortierung",3
),
ADDCOLUMNS(
PREVIOUSYEAR(DATESYTD(Kalender[Date])),
"Filter","letztes Jahr","Sortierung",4
),
ADDCOLUMNS(
PREVIOUSQUARTER(DATESQTD(Kalender[Date])),
"Filter","letztes Quartal","Sortierung",5
),
ADDCOLUMNS(
PREVIOUSMONTH(DATESMTD(Kalender[Date])),
"Filter","letzter Monat","Sortierung",6
),
ADDCOLUMNS(
CALENDAR(MIN(Kalender[Date]),Max(Kalender[Date])),
"Filter","Alle","Sortierung",7
),
ADDCOLUMNS(
DATESINPERIOD(Kalender[Date],MAX(Kalender[Date]),-12,MONTH ),
"Filter","letzten 12 Monate","Sortierung",0
) )

--- SCHNAPP ---



Kommentare

Kommentar veröffentlichen

Beliebte Posts aus diesem Blog

Dropdown Liste mit Mehrfachauswahl

Bild
Standardmäßig kann in einem Dropdownfeld nur ein Eintrag ausgewählt werden (Daten -> Datentools -> Datenüberprüfung). Ein dynamisches Dropdownfeld kann folgendermaßen realisiert werden abhängige, dynamische Dropdownfelder können folgendermaßen in Excel  realisiert werden weiterführende Informationen siehe hier Um eine Mehrfachauswahl zu realisieren, kann der folgende VBA-Code im betreffenden Arbeitsblatt verwendet werden (rechte Maustaste auf Arbeitsblatt -> Code einfügen). --- SCHNIPP -- Private Sub Worksheet_Change(ByVal Target As Range) '** Mehrfachauswahl über DropDown-Liste (Gültigkeitsprüfung) '** Einfügen im Code-Container des betreffenden Arbeitsblattes '** Dimensionierung der Variablen Dim rngDV As Range Dim wert_old As String Dim wertnew As String '** Errorhandling On Error GoTo Errorhandling '** Mehrfachauswahl im definierten Bereich (Bsp. B4:B14) durchführen If Not Application.Intersect(Target, Range("B4:B14&
Mehr anzeigen

Vergleich mit 2 Bedingungen, INDEX(), VERGLEICH()

Wenn man 2 Tabellen mit jeweils 2 gleichen Spalten hat (zB Nachnahme, Vorname) und eine 3te Spalte (zB Telefon) von einer Tabelle in eine andere übernehmen will, stellt die Funktion SVERWEIS() keinen adäquaten Lösungsansatz mehr dar. Mit einer Kombination der Funktionen INDEX() und VERGLEICH() ist es dennoch möglich, diese Aufgabe mit Excel Formeln (Matrixformel) zu lösen. =INDEX(Tabelle1!$A$2:$C$5;VERGLEICH(A2&B2;Tabelle1!$A$2:$A$5&Tabelle1!$B$2:$B$5;0);3) wobei gilt: Tabelle 1 Spalte A zB Nachname Tabelle 1 Spalte B zB Vorname Tabelle 1 Spalte C zB Telefon (Wert welcher in Tabelle 2 bei inhaltlicher Gleichheit Spalten A, B übernommen werden soll) Formel in Tabelle 2 Spalte C aufbauen und mit STRG-SHIFT-RETURN (Matrixformel) abschließen und runterkopieren. Ein weiteres Beispiel zu Matrixformeln siehe folgenden Blog Beitrag seit Office 365 -> Microsoft 365 gibt es eine weitere, neue Alternative, Funktion XVERWEIS()
Mehr anzeigen

nützliche Text Funktionen in Power Query

Bild
Im Folgenden werden ein paar in der Praxis nützliche Text Funktionen in Power Query aufgelistet. Im Voraus soll darauf hingewiesen werden, dass es 2 wesentliche Unterschiede zwischen Excel und Power Query Formeln / Funktionen gibt: case sensitivity Excel Formel unterscheiden nicht zwischen Groß- und Kleinschreibung, Power Query Formeln indes schon. Wenn eine Power Query Signatur Text.Range vorgibt, dann wird TEXT.RANGE oder text.range nicht funktionieren (case sensitive). Basis 1 versus Basis 0 Excel Formeln / Funktionen beziehen sich immer auf die Basis 1, d.h. man fängt mit 1 an zu zählen. Auf der anderen Seite startet das Zählen in einer Power Query Funktion immer mit 0, nicht 1. Vergleich Excel Text mit Power Query Funktionen Text.Contains(Text,Suchstring) gibt TRUE zurück, wenn <Suchstring> in <Text> beinhaltet ist, andernfalls FALSE z.B. Text.Contains("Power Query","Query") Rückgabewert = TRUE Text.Remove([Column],{"
Mehr anzeigen